@ECHO OFF

SET IP=192.168.1.134

SET BAT=0
IF "%~1" NEQ "" (
    SET IP=%1
    SET BAT=1
)

SET CURDIR=%~dp0
SET CURDIR=%CURDIR:~0,-1%

SET  TMPDIR=tmp
SET  DEVDIR=/root

SET PSCP=%CURDIR%\tools\pscp 
SET PLINK=%CURDIR%\tools\plink

SET USR=root
SET FBAT=%CURDIR%\tools\script.sh
SET PWD=gowone123
SET FILES=pdutar logo.png smartPDU.ini

::enterin current directory
CD %CURDIR%

::copy files
MKDIR  %TMPDIR% 2>NUL
FOR %%x IN (%FILES%) DO (
    XCOPY /DQY %%x  %TMPDIR%\  > NUL
)

::test ip
ECHO ping %IP% ...
PING -n 3 -w 500 %IP%  >NUL
IF %ERRORLEVEL% NEQ 0 (
    IF %BAT% EQU 0 (
    ECHO %IP% can't reached!
        TIMEOUT /T 2 > NUL
    )
    EXIT /B 1
)

::send files
ECHO send %TMPDIR% to device ...
ECHO  y  | %PSCP% -pw %PWD% -r %TMPDIR% %USR%@%IP%:%DEVDIR%
IF %ERRORLEVEL% NEQ 0 (
    ECHO send failed!
    EXIT /B 2
)

ECHO send finished, release files now ...
ECHO  y  | %PLINK%  -ssh -t  -pw %PWD% %USR%@%IP% -m %FBAT%
IF %ERRORLEVEL% NEQ 0 (
    ECHO upgrade failed!
    EXIT /B 3
)

IF %BAT% EQU 0 (
    ECHO quit now ...
    TIMEOUT /T 2 > NUL
)

EXIT /B 0